Getting Two I2C Displays Working At Once On An Arduino

Ms Geek gave me an Arduino Leonardo a little while ago and from the moment she showed me how to get it to blink an LED, I’ve been hooked. I’ve been in the PIC camp for almost 20 years now, but the build environment and ease of use of the Arduino blew my mind and I’ve been tinkering with them every day since that little “L” LED blinked.

One of the things I wanted to do was get a display working. I played around with some of the old HD44780 LCDs that have been collecting a very thick coat of dust and they worked well enough, but something I’ve never done is use a graphic display. TFT displays were always expensive (and still kind of are), but nowadays there seems to be quite the selection of small OLED displays that are quite inexpensive.

I did some shopping around and found a deal on some 128×32 pixel displays as well as one 128×64 pixel display, both of which speak I2C. It was pretty easy getting them working with the Leonardo and the u8g2 library, and while you can fit a surprising amount of information on even a 128x32px display, I have some other ideas for other projects where it would be useful to have two displays working at the same time.

Here are the two displays I wanted to use. On the left is the 128x64px display that has a SH1106 controller, on the right is the 128x32px display that has an SSD1306 controller. Both are 5V tolerant, so they’re easy to connect to the Leonardo. The origin is the same on both – at the top left of the display.

One of the nice things about I2C is that you can select individual devices by address. No extra wires needed, just send the right signals down the wires and you’re talking to whichever device you’d like. The flexibility of addressing in I2C has its drawbacks, though. If you want to use multiple devices without any external circuitry, each device needs a different address.

Both of the displays came configured with the same address – 0x78 (or 0x30 if you’re treating it as a seven-bit address). The 128x32px display doesn’t seem to have any way to change the address, but by moving a tiny surface-mount resistor on the 128x64px display, I was able to change the address from 0x78(0x30) to 0x7A(0x3C):

Believe it or not, I’ve been soldering for 35 years and I’ve taken high-reliability soldering courses, but that was back in the day when my eyes still focused well, my hands didn’t shake, and the nerves in my right arm were still working properly. Hooo boy it was pretty frustrating to move that resistor over. On this display it was 4k7, next time I may just use a 1/4 watt resistor instead of the SMD. Regardless, my crappy soldering was good enough to change the address of the display.

Hooking everything up was easy. The Leonardo has breakout pins for hardware SDA and SCL lines, but I have some Pro Micro and Nanos that I’d like to use so I used the numbered digital pins instead (obviously, if you’re using something other than the Leonardo, you’ll need to check the pinout of your device for the right pins). In the Leonardo’s (and Pro Micro’s) case, the I2C pins are 2(SDA) and 3(SCL). It’s possible that 4k7 pullups might be needed on the SDA and SCL pins when using more than one device; in this case things seemed to work fine without them. Here it is, in all it’s connected glory:

I frequently leave the film protectors on stuff I buy. Makes me think that it’s still brand new, even when it’s not.

So, with two displays with different I2C addresses hooked up, I was able to get each one working individually just by changing the constructor and address. Getting both working at the same time took a little bit of work, but the Arduino Wire and u8g2 library reference pages and example programs had the information I needed. Here’s the program:

// LEONARDO - TWO I2C OLEDS
// Using two displays: the 128x64 SH1106 OLED (0x3C/0x78), and the 128x32 SSD1306
// (0x3D/0x7A).
// The 128x64 display will be DISPA, the 128x32 display will be DISPB.
// This program is a bit of a pig, using 60% of the program storage space and 95% of
// the dynamic memory.
// Sometimes when running this program, the Leonardo doesn't respond to serial port
// data/uploads. If that happens, start the compile/upload, immediately ground the
// RESET pin very briefly, and it should work.
// **THIS PROGRAM IS FREE TO USE AND MODIFY AS YOU SEE FIT**

// Need this to use the I2C bus. I2C pins on Leonardo are broken
// out but are also 2 (SDA) and 3 (SCL).
#include <Wire.h> 

// Need this to make displays do things and stuff.
#include <U8g2lib.h> 

// Select proper constructor (driver) for this particular 128x64 OLED display and
// call it DISPA. See https://github.com/olikraus/u8g2/wiki/u8g2setupcpp for other
// drivers. There are lots of different OLED board configurations out there!
U8G2_SH1106_128X64_NONAME_F_HW_I2C DISPA(U8G2_R0, /* reset=*/ U8X8_PIN_NONE);
                                                                              
// Select constructor for this particular 128x32 OLED display, call it DISPB.                                                                               
U8G2_SSD1306_128X32_UNIVISION_F_HW_I2C DISPB(U8G2_R0, U8X8_PIN_NONE);

// Set aliases for the I2C pins. They're broken out on the Leonardo but I'm using
// the numbered pins so it's seamless with other boards like the Pro Micro.
#define SDA 2  
#define SCL 3


void setup() {
  // put your setup code here, to run once:

  // Setting the pins that control the displays to all outputs. There are no inputs
  // on these two OLED displays to worry about - others may be different!
  pinMode(SDA, OUTPUT);  
  pinMode(SCL, OUTPUT);


  // Set I2C bus speed on Arduino and both displays. This may not be necessary
  // but I put it in anyway - one less thing to troubleshoot if things don't work.
  Wire.setClock(100000);
  DISPA.setBusClock(100000);
  DISPB.setBusClock(100000);

  // Some devices say they're 0x78/0x7A, but others may say they're 0x3C/0x3D. It's
  // like that because the address is 7 bits but some places (u8g2 included) pad it
  // out to 8 bits. Adding a 0 on the end multiplies the value by 2.
  // Most of the small OLED displays out there seem to be set to 0x3C(0x78). Some
  // can be changed, but not all of them.
  // See https://www.arduino.cc/en/Reference/Wire for details.
  DISPA.setI2CAddress(0x7A);
  DISPB.setI2CAddress(0x78);
  
  // Fire up the displays and get them ready to accept data.
  // Remember, DISPA is the 128x64px OLED, DISPB is the 128x32px OLED.                           
  DISPA.begin();
  DISPB.begin();

  // Select a font to use on DISPA and DISPB. They don't have to be the same, and
  // you can change them throughout the program, too. 
  // Check https://github.com/olikraus/u8g2/wiki for others, there are LOTS.
  DISPA.setFont(u8g2_font_logisoso30_tf );
  DISPB.setFont(u8g2_font_logisoso30_tf );

  // Let's put some writing on DISPA. Make sure the display buffer is clear before
  // writing or drawing anything.
  DISPA.clearBuffer();

  // Move the starting position of what will be written/drawn next to x=0, y=32.
  // As shown in the above picture, coordinates start at 0,0 at the top left.
  // If you want to properly display text, make sure you set the y-value to at least
  // as large as how many pixels tall your font is.
  // If your display shows nothing, make sure you have set the y-value or everything
  // will end up being drawn beyond the edges of the display...
  DISPA.setCursor(0, 32); 
  
  // This just puts Howdy! in the selected font in the buffer. Nothing gets written
  // to the screen yet. You could move the cursor position again and write more text
  // to the buffer or draw some shapes if you wanted. At this point you're just
  // setting bits that will turn on the associated pixels.
  // See https://github.com/olikraus/u8g2/wiki/u8g2reference to find out how to
  // draw shapes and lines or even set individual pixels.
  DISPA.print("Howdy!");  

  // Take whatever's been written or drawn in the buffer and send it to the display.
  DISPA.sendBuffer(); 

  // Now, do the same thing for DISPB.
  DISPB.clearBuffer();  
  DISPB.setCursor(0, 31);
  DISPB.print("Hi!");
  DISPB.sendBuffer();

  delay(2000);  // Wait two seconds to admire the displays before moving on.

}

void loop() {
  // put your main code here, to run repeatedly:

  // All this code does is say "HELLO" and show a count up on DISPA, while 
  // counting down on DISPB.

  byte CountUp = 0;
  while (CountUp <= 255) {
    DISPA.clearBuffer();
    DISPA.setCursor(0, 31);
    DISPA.print("HELLO");
    DISPA.setCursor(40, 63);
    DISPA.print(CountUp);
    DISPA.sendBuffer();

    DISPB.clearBuffer();
    DISPB.setCursor(40, 31);
    DISPB.print(255 - CountUp);
    DISPB.sendBuffer();
    CountUp = CountUp + 1;
    delay(100);
  }
  delay(500);  // Wait 500ms and do it again.
}

Here’s what it looks like when it’s running:

I am not a programmer, but there’s really not all that much to this particular project. Like I mention in the code, sometimes when the Leonardo is running this program, the Arduino programmer won’t be able to connect with the board. My guess is that it’s because almost all of the memory is used up, but I’m not sure. Anyway, what you need to do is start the compile/upload, immediately ground the RESET pin briefly (a quick tap will do), and watch the screen. Sometimes I have to do it more than once, but don’t panic if your board isn’t responding – it’s not dead.

I’ve only tried this on the Leonardo and the Pro Micro, both of which use the ATmega32u4 MCU.

Leave a Reply

Your email address will not be published. Required fields are marked *